Spaces:
Paused
Paused
File size: 9,214 Bytes
343e5a8 |
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 |
/*
Copyright (c) 2008, Adobe Systems Incorporated
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are
met:
* Redistributions of source code must retain the above copyright notice,
this list of conditions and the following disclaimer.
* Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.
* Neither the name of Adobe Systems Incorporated nor the names of its
contributors may be used to endorse or promote products derived from
this software without specific prior written permission.
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
package com.carrot.adobe.serialization.json
{
public class JSONDecoder
{
/**
* Flag indicating if the parser should be strict about the format
* of the JSON string it is attempting to decode.
*/
private var strict:Boolean;
/** The value that will get parsed from the JSON string */
private var value:*;
/** The tokenizer designated to read the JSON string */
private var tokenizer:JSONTokenizer;
/** The current token from the tokenizer */
private var token:JSONToken;
/**
* Constructs a new JSONDecoder to parse a JSON string
* into a native object.
*
* @param s The JSON string to be converted
* into a native object
* @param strict Flag indicating if the JSON string needs to
* strictly match the JSON standard or not.
* @langversion ActionScript 3.0
* @playerversion Flash 9.0
* @tiptext
*/
public function JSONDecoder( s:String, strict:Boolean )
{
this.strict = strict;
tokenizer = new JSONTokenizer( s, strict );
nextToken();
value = parseValue();
// Make sure the input stream is empty
if ( strict && nextToken() != null )
{
tokenizer.parseError( "Unexpected characters left in input stream" );
}
}
/**
* Gets the internal object that was created by parsing
* the JSON string passed to the constructor.
*
* @return The internal object representation of the JSON
* string that was passed to the constructor
* @langversion ActionScript 3.0
* @playerversion Flash 9.0
* @tiptext
*/
public function getValue():*
{
return value;
}
/**
* Returns the next token from the tokenzier reading
* the JSON string
*/
private function nextToken():JSONToken
{
return token = tokenizer.getNextToken();
}
/**
* Attempt to parse an array.
*/
private function parseArray():Array
{
// create an array internally that we're going to attempt
// to parse from the tokenizer
var a:Array = new Array();
// grab the next token from the tokenizer to move
// past the opening [
nextToken();
// check to see if we have an empty array
if ( token.type == JSONTokenType.RIGHT_BRACKET )
{
// we're done reading the array, so return it
return a;
}
// in non-strict mode an empty array is also a comma
// followed by a right bracket
else if ( !strict && token.type == JSONTokenType.COMMA )
{
// move past the comma
nextToken();
// check to see if we're reached the end of the array
if ( token.type == JSONTokenType.RIGHT_BRACKET )
{
return a;
}
else
{
tokenizer.parseError( "Leading commas are not supported. Expecting ']' but found " + token.value );
}
}
// deal with elements of the array, and use an "infinite"
// loop because we could have any amount of elements
while ( true )
{
// read in the value and add it to the array
a.push( parseValue() );
// after the value there should be a ] or a ,
nextToken();
if ( token.type == JSONTokenType.RIGHT_BRACKET )
{
// we're done reading the array, so return it
return a;
}
else if ( token.type == JSONTokenType.COMMA )
{
// move past the comma and read another value
nextToken();
// Allow arrays to have a comma after the last element
// if the decoder is not in strict mode
if ( !strict )
{
// Reached ",]" as the end of the array, so return it
if ( token.type == JSONTokenType.RIGHT_BRACKET )
{
return a;
}
}
}
else
{
tokenizer.parseError( "Expecting ] or , but found " + token.value );
}
}
return null;
}
/**
* Attempt to parse an object.
*/
private function parseObject():Object
{
// create the object internally that we're going to
// attempt to parse from the tokenizer
var o:Object = new Object();
// store the string part of an object member so
// that we can assign it a value in the object
var key:String
// grab the next token from the tokenizer
nextToken();
// check to see if we have an empty object
if ( token.type == JSONTokenType.RIGHT_BRACE )
{
// we're done reading the object, so return it
return o;
}
// in non-strict mode an empty object is also a comma
// followed by a right bracket
else if ( !strict && token.type == JSONTokenType.COMMA )
{
// move past the comma
nextToken();
// check to see if we're reached the end of the object
if ( token.type == JSONTokenType.RIGHT_BRACE )
{
return o;
}
else
{
tokenizer.parseError( "Leading commas are not supported. Expecting '}' but found " + token.value );
}
}
// deal with members of the object, and use an "infinite"
// loop because we could have any amount of members
while ( true )
{
if ( token.type == JSONTokenType.STRING )
{
// the string value we read is the key for the object
key = String( token.value );
// move past the string to see what's next
nextToken();
// after the string there should be a :
if ( token.type == JSONTokenType.COLON )
{
// move past the : and read/assign a value for the key
nextToken();
o[key] = parseValue();
// move past the value to see what's next
nextToken();
// after the value there's either a } or a ,
if ( token.type == JSONTokenType.RIGHT_BRACE )
{
// we're done reading the object, so return it
return o;
}
else if ( token.type == JSONTokenType.COMMA )
{
// skip past the comma and read another member
nextToken();
// Allow objects to have a comma after the last member
// if the decoder is not in strict mode
if ( !strict )
{
// Reached ",}" as the end of the object, so return it
if ( token.type == JSONTokenType.RIGHT_BRACE )
{
return o;
}
}
}
else
{
tokenizer.parseError( "Expecting } or , but found " + token.value );
}
}
else
{
tokenizer.parseError( "Expecting : but found " + token.value );
}
}
else
{
tokenizer.parseError( "Expecting string but found " + token.value );
}
}
return null;
}
/**
* Attempt to parse a value
*/
private function parseValue():Object
{
// Catch errors when the input stream ends abruptly
if ( token == null )
{
tokenizer.parseError( "Unexpected end of input" );
}
switch ( token.type )
{
case JSONTokenType.LEFT_BRACE:
return parseObject();
case JSONTokenType.LEFT_BRACKET:
return parseArray();
case JSONTokenType.STRING:
case JSONTokenType.NUMBER:
case JSONTokenType.TRUE:
case JSONTokenType.FALSE:
case JSONTokenType.NULL:
return token.value;
case JSONTokenType.NAN:
if ( !strict )
{
return token.value;
}
else
{
tokenizer.parseError( "Unexpected " + token.value );
}
default:
tokenizer.parseError( "Unexpected " + token.value );
}
return null;
}
}
}
|